KY-022 Infrarot-Receiver

Dieses Modul kann Infrarotsignale empfangen und wandelt diese in digitale Signale um, die am Ausgang ausgegeben werden. Wenn ein Infrarotsignal erkannt wird, blinkt eine integrierte LED auf dem Modul kurz auf, was eine visuelle Bestätigung des Signalempfangs bietet. Es ist ideal für Projekte, bei denen Infrarotfernbedienungen oder andere Infrarotsignale verwendet werden. Dank seiner einfachen Handhabung und zuverlässigen Signalverarbeitung lässt sich das Modul leicht in verschiedene Elektronikprojekte integrieren, um beispielsweise Fernsteuerungen zu realisieren oder Daten drahtlos zu übertragen.

Anschlussbelegung

Code-Beispiel

Mit Hilfe der beiden Sensormodule KY-005 und KY-022 lässt sich ein System mit Infrarot-Fernbedienung und Infrarot-Empfänger aufbauen. Hierzu werden neben den beiden Modulen auch zwei Arduinos benötigt. Diese fungieren hierbei dann jeweils als Sender und als Empfänger der Signale.

Mithilfe des Sensormodules KY-022 lässt sich ein Infrarot-Receiver aufbauen. Hierzu werden nur das Infrarot Receiver Modul und ein einzelner Arduino benötigt. Dieser fungiert hierbei dann als Empfänger und gibt die Signale dann in der seriellen Konsole aus.

Um das folgende Codebeispiel auf Ihren Arduino zu laden, empfehlen wir die Verwendung der Arduino IDE. In der IDE können Sie den passenden Port und das richtige Board für Ihr Gerät auswählen. Für das folgende Codebeispiel wird eine zusätzliche Library benötigt:

IRremote von Ken Shirriff | veröffentlicht unter der MIT Lizenz

Diese Bibliotheken können Sie bequem über den Bibliotheken-Manager der Arduino IDE hinzufügen.

Bei Infrarot-Sende- und Empfängersystemen, gibt es verschiedene Protokolle, in denen die Daten versendet und empfangen werden können. In dem folgenden Beispiel wird für das Empfangen das modifizierte SimpleReceiver Beispiel verwendet - die verwendete Library IRremote kümmert sich eigenständig um die Konvertierung in die richtige Datenfolge. Es gibt innerhalb der Library jedoch auch andere Protokolle/Kodierungen - diese sind in der Dokumentation/dem Code der Library gekennzeichnet. Dokumentation

Bitte beachten Sie: Für die Ausführung des Codebeispiels ist eine zusätzliche Datei notwendig. Diese öffnet sich automatisch, sobald Sie den Beispielcode aus der IRremote-Bibliothek öffnen. Öffnen Sie daher zunächst den Beispielcode über den folgenden Weg: Datei > Beispiele > IRremote > SimpleReceiver.

Nun können Sie den Beispielcode durch unser modifiziertes Beispiel ersetzen. Um den Code auf Ihren Arduino hochzuladen, klicken Sie einfach auf den Upload-Button.

/*
 * SimpleReceiver.cpp
 *
 * Demonstriert den Empfang von NUR NEC-Protokoll-IR-Codes mit IRremote.
 * Wenn kein Protokoll definiert ist, sind alle Protokolle (außer Bang&Olufsen) aktiv.
 *
 *  Diese Datei ist Teil von Arduino-IRremote https://github.com/Arduino-IRremote/Arduino-IRremote.
 *
 ************************************************************************************
 * MIT License
 *
 * Copyright (c) 2020-2023 Armin Joachimsmeyer
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is furnished
 * to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in all
 * copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
 * INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A
 * PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
 * HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF
 * CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE
 * OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
 *
 ************************************************************************************
 */

#include <Arduino.h>

/*
 * Geben Sie an, welche(s) Protokoll(e) für die Dekodierung verwendet werden soll(en).
 * Wenn kein Protokoll definiert ist, sind alle Protokolle (außer Bang&Olufsen) aktiv.
 * Dies muss vor dem #include <IRremote.hpp> erfolgen.
 */
//#define DECODE_DENON        // Beinhaltet Sharp
//#define DECODE_JVC
//#define DECODE_KASEIKYO
//#define DECODE_PANASONIC    // Alias für DECODE_KASEIKYO
//#define DECODE_LG
#define DECODE_NEC          // Beinhaltet Apple und Onkyo. Um alle Protokolle zu aktivieren, kommentieren/deaktivieren Sie einfach diese Zeile.
//#define DECODE_SAMSUNG
//#define DECODE_SONY
//#define DECODE_RC5
//#define DECODE_RC6

//#define DECODE_BOSEWAVE
//#define DECODE_LEGO_PF
//#define DECODE_MAGIQUEST
//#define DECODE_WHYNTER
//#define DECODE_FAST

//#define DECODE_DISTANCE_WIDTH // Universaldecoder für Impulsabstandsprotokolle
//#define DECODE_HASH         // spezieller Decoder für alle Protokolle

//#define DECODE_BEO          // Dieses Protokoll muss immer manuell aktiviert werden, d.h. es ist NICHT aktiviert, wenn kein Protokoll definiert ist. Es verhindert die Dekodierung von SONY!

//#define DEBUG               // Aktivieren Sie dies, um viele schöne Debug-Ausgaben von den Decodern zu erhalten.

//#define RAW_BUFFER_LENGTH  750 // Für Fernbedienungen von Klimaanlagen sind 750 erforderlich. Standard ist 200.

/*
 * Dieses Include definiert die aktuellen Pin-Nummern für Pins wie IR_RECEIVE_PIN, IR_SEND_PIN für viele verschiedene Boards und Architekturen
 */
#include "PinDefinitionsAndMore.h"
#include <IRremote.hpp> // Einbindung der Bibliothek

void setup() {
    Serial.begin(115200);
    while (!Serial)
        ; // Warten Sie darauf, dass Serial verfügbar wird. Wird für einige Kerne wegoptimiert.

    // Starten des Empfängers und, falls kein 3. Parameter angegeben, Übernahme des LED_BUILTIN-Pins aus der internen Kartendefinition als Standard-Feedback-LED
    IrReceiver.begin(IR_RECEIVE_PIN, ENABLE_LED_FEEDBACK);
    Serial.println(F("KY-022: Infrarot Empfänger Test"));
    Serial.print(F("Bereit zum Empfang von IR-Signalen von Protokollen: "));
    printActiveIRProtocols(&Serial);
    Serial.println(F("am Pin " STR(IR_RECEIVE_PIN)));
}

void loop() {
    /*
     * Prüfen, ob empfangene Daten verfügbar sind, und wenn ja, versuchen, sie zu dekodieren.
     * Das dekodierte Ergebnis befindet sich in der Struktur IrReceiver.decodedIRData.
     *
     * z.B. Befehl steht in IrReceiver.decodedIRData.command
     * Adresse steht in Befehl steht in IrReceiver.decodedIRData.address
     * und bis zu 32 Bit Rohdaten in IrReceiver.decodedIRData.decodedRawData
     */
    if (IrReceiver.decode()) {
        /*
         * Gibt eine Zusammenfassung der empfangenen Daten aus
         */
        if (IrReceiver.decodedIRData.protocol == UNKNOWN) {
            Serial.println(F("Empfangenes Rauschen oder ein unbekanntes (oder noch nicht aktiviertes) Protokoll"));
            // Wir haben hier ein unbekanntes Protokoll, geben Sie erweiterte Informationen aus
            IrReceiver.printIRResultRawFormatted(&Serial, true);
            IrReceiver.resume(); // Tun Sie es hier, um die Rohdaten für die Ausgabe mit printIRResultRawFormatted() zu erhalten.
        } 
        else {
            IrReceiver.resume(); // Frühzeitige Freigabe des Empfangs des nächsten IR-Frames
            IrReceiver.printIRResultShort(&Serial);
        }
    }
}