KY-005 Infrarot-Transmitter

Dieses Modul enthält eine Leuchtdiode, die Infrarotlicht aussendet. Infrarotlicht ist für das menschliche Auge unsichtbar, aber es wird häufig in vielen praktischen Anwendungen verwendet, wie z.B. bei Fernbedienungen oder in der Objekterkennung. Die Diode arbeitet mit einer Spannung von 1,1 V und einem Strom von 20 mA. Je nach Eingangsspannung ist es wichtig, Vorwiderstände zu verwenden, um die Leuchtdiode zu schützen und einen reibungslosen Betrieb zu gewährleisten. Diese Vorwiderstände stellen sicher, dass die richtige Menge an Strom durch die Diode fließt, wodurch sie effektiv und sicher genutzt werden kann. Das Modul eignet sich hervorragend für Projekte, die Infrarotlicht benötigen, und bietet eine zuverlässige und einfache Lösung für Ihre Infrarotanwendungen.

Vorwiderstände:

Anschlussbelegung

für Fortgeschrittenere

Auf der Platine gibt es die Möglichkeit, den jeweils benötigten Widerstand direkt aufzulöten. Die Stelle zum Auflöten des Widerstandes befindet sich direkt über den Anschlusspins auf dem PCB.

Beim Auflöten des Widerstandes ändert sich die Anschlussbelegung wie folgt:

für Anfänger

Codebeispiel

Mit Hilfe der beiden Sensormodule KY-005 und KY-022 lässt sich ein System mit Infrarot-Fernbedienung und Infrarot-Empfänger aufbauen. Hierzu werden neben den beiden Modulen auch zwei Arduinos benötigt. Diese fungieren hierbei dann jeweils als Sender und als Empfänger der Signale.

Um das folgende Codebeispiel auf Ihren Arduino zu laden, empfehlen wir die Verwendung der Arduino IDE. In der IDE können Sie den passenden Port und das richtige Board für Ihr Gerät auswählen. Für das folgende Codebeispiel wird eine zusätzliche Library benötigt:

IRremote von Ken Shirriff | veröffentlicht unter der MIT Lizenz

Diese Bibliotheken können Sie bequem über den Bibliotheken-Manager der Arduino IDE hinzufügen.

Bei Infrarot-Sendesystemen gibt es verschiedene Protokolle, in denen die Daten versendet werden können. In dem folgenden Beispiel wird für das Versenden das NEC-Protokoll verwendet. Dokumentation

Bitte beachten Sie: Für die Ausführung des Codebeispiels ist eine zusätzliche Datei notwendig. Diese öffnet sich automatisch, sobald Sie den Beispielcode aus der IRremote-Bibliothek öffnen. Öffnen Sie daher zunächst den Beispielcode über den folgenden Weg: Datei > Beispiele > IRremote > SimpleSender. Nun können Sie den Beispielcode durch unser modifiziertes Beispiel ersetzen. Um den Code auf Ihren Arduino hochzuladen, klicken Sie einfach auf den Upload-Button.

/*
 * SimpleSender.cpp
 *
 * Demonstriert das Senden von IR-Codes im Standardformat mit Adresse und Befehl
 * Ein erweitertes Beispiel zum Senden finden Sie als SendDemo.
 *
 *  Copyright (C) 2020-2022  Armin Joachimsmeyer
 *  armin.joachimsmeyer@gmail.com
 *
 *  Diese Datei ist Teil von Arduino-IRremote https://github.com/Arduino-IRremote/Arduino-IRremote.
 *
 *  MIT License
 */
#include <Arduino.h>

#if !defined(ARDUINO_ESP32C3_DEV) // Dies ist auf einen Fehler im RISC-V-Compiler zurückzuführen, der unbenutzte Funktionsabschnitte benötigt :-(.
// Deaktiviert statischen Empfängercode wie den ISR-Handler für den Empfangstimer und statische IRReceiver- und irparams-Daten. 
// Spart 450 Byte Programmspeicher und 269 Byte RAM, wenn die Empfangsfunktionen nicht benötigt werden.
#define DISABLE_CODE_FOR_RECEIVER 
#endif

/*
 * Dieses Include definiert die aktuellen Pin-Nummern für Pins wie IR_RECEIVE_PIN, IR_SEND_PIN für viele verschiedene Boards und Architekturen
 */
#include "PinDefinitionsAndMore.h"
#include <IRremote.hpp> // Einbindung der Bibliothek

void setup() {
    pinMode(LED_BUILTIN, OUTPUT);

    Serial.begin(115200);
    while (!Serial)
        ; // Warten Sie darauf, dass Serial verfügbar wird. Wird für einige Kerne wegoptimiert.

    // Nur um zu wissen, welches Programm auf meinem Arduino läuft
    Serial.println(F("KY-005: Infrarot Sender Test"));
    Serial.print(F("Sende IR-Signale an Pin "));
    Serial.println(IR_SEND_PIN);

    /*
     * Die Einrichtung der IR-Bibliothek. Das war's schon!
     */
    // Beginnen Sie mit IR_SEND_PIN -der in PinDefinitionsAndMore.h definiert ist- als Sende-Pin und aktivieren Sie die Rückmelde-LED am Standard-Rückmelde-LED-Pin
    IrSender.begin();
    disableLEDFeedback(); // Rückmelde-LED am Standard-Rückmelde-LED-Pin deaktivieren
}

/*
 * Einrichten der zu sendenden Daten.
 * Bei den meisten Protokollen werden die Daten mit einer konstanten 8- (oder 16-Byte-) Adresse
 * und einem variablen 8-Bit-Befehl.
 * Es gibt Ausnahmen wie Sony und Denon, die eine 5-Bit-Adresse haben.
 */
uint8_t sCommand = 0x34;
uint8_t sRepeats = 0;

void loop() {
    /*
     * Aktuelle Sendewerte anzeigen
     */
    Serial.println();
    Serial.print(F("Jetzt wird gesendet: Adresse=0x00, Command=0x"));
    Serial.print(sCommand, HEX);
    Serial.print(F(", Wiederholungen="));
    Serial.print(sRepeats);
    Serial.println();

    Serial.println(F("Senden von Standard-NEC mit 8-Bit-Adresse"));
    Serial.flush();

    // Der Empfängerausgang für die erste Schleife muss sein: Protocol=NEC Address=0x102 Command=0x34 Raw-Data=0xCB340102 (32 bits)
    IrSender.sendNEC(0x00, sCommand, sRepeats);

    /*
     * Sendewerte inkrementieren
     */
    sCommand += 0x11;
    sRepeats++;
    // Clip wiederholt sich bei 4
    if (sRepeats > 4) {
        sRepeats = 4;
    }

    delay(1000);  // Verzögerung muss größer als 5 ms sein (RECORD_GAP_MICROS), sonst sieht der Empfänger es als ein langes Signal
}