KY-005 Module transmetteur infrarouge

Ce module contient une diode électroluminescente qui émet une lumière infrarouge. La lumière infrarouge est invisible pour l'œil humain, mais elle est souvent utilisée dans de nombreuses applications pratiques, comme les télécommandes ou la détection d'objets. La diode fonctionne avec une tension de 1,1 V et un courant de 20 mA. En fonction de la tension d'entrée, il est important d'utiliser des résistances préalables pour protéger la diode électroluminescente et garantir un fonctionnement sans problème. Ces pré-résistances garantissent que la bonne quantité de courant circule dans la diode, ce qui permet de l'utiliser efficacement et en toute sécurité. Ce module est idéal pour les projets nécessitant une lumière infrarouge et offre une solution fiable et simple pour vos applications infrarouges.

Les désignations (Vf et If) font référence à la tension directe et au courant direct de la diode électroluminescente.

Résistances de série:

Affectation des broches

pour les plus avancés

Sur le circuit imprimé, il est possible de souder directement la résistance requise. L'emplacement pour souder la résistance est situé directement au-dessus des broches de connexion sur le circuit imprimé.

Lors du soudage de la résistance, l'affectation des bornes est modifiée comme suit :

pour les débutants

Exemple de code

En utilisant les deux modules capteurs KY-005 et KY-022, il est possible de construire un système télécommande infrarouge + récepteur infrarouge. Pour ce faire, deux Arduinos sont nécessaires en plus des deux modules. Ceux-ci agissent alors comme un émetteur et comme un récepteur des signaux. Il est seulement important de savoir ce que le récepteur des signaux de la console série émet et ce que l'émetteur envoie, car cela doit correspondre.

Pour charger l'exemple de code suivant sur votre Arduino, nous vous recommandons d'utiliser l'IDE Arduino. Dans l'IDE, vous pouvez choisir le port et la carte qui conviennent à votre appareil.Les bibliothèques suivantes sont également utilisées pour l'exemple de code :

IRremote par Ken Shirriff | publié sous la licence MIT.

Vous pouvez facilement ajouter ces bibliothèques via le gestionnaire de bibliothèques de l'IDE Arduino.

Avec les systèmes de transmission infrarouge, il existe différents protocoles dans lesquels les données peuvent être envoyées. Dans l'exemple suivant, le protocole NEC est utilisé pour l'envoi à l'aide de l'exemple SimpleSender modifié et de l'exemple SimpleReceiver modifié - la bibliothèque utilisée IRremote s'occupe indépendamment de la conversion en séquence de données correcte. Cependant, il existe d'autres protocoles/encodages au sein de la bibliothèque - ceux-ci sont identifiés dans la documentation/code de la bibliothèque. Documentation.

Veuillez noter: Pour l'exécution de l'exemple de code, un fichier supplémentaire est nécessaire. Celui-ci s'ouvre automatiquement dès que vous ouvrez le code d'exemple de la bibliothèque IRremote. Ouvrez donc d'abord le code d'exemple de la manière suivante : Fichier > Exemples > IRremote > SimpleSender.

Vous pouvez maintenant remplacer le code d'exemple par notre exemple modifié. Pour télécharger le code sur l'Arduino, il suffit de cliquer sur le bouton " Upload ".

/*
 * SimpleSender.cpp
 *
 * Démonstration de l'envoi de codes IR au format standard avec adresse et commande.
 * Vous trouverez un exemple avancé d'envoi sous SendDemo.
 *
 *  Copyright (C) 2020-2022  Armin Joachimsmeyer
 *  armin.joachimsmeyer@gmail.com
 *
 * Ce fichier fait partie de Arduino-IRremote https://github.com/Arduino-IRremote/Arduino-IRremote.
 *
 *  MIT License
 */
#include <Arduino.h>

#if !defined(ARDUINO_ESP32C3_DEV) // Ceci est dû à une erreur dans le compilateur RISC-V qui nécessite des sections de fonction inutilisées :-(.
// Désactive le code statique du récepteur comme le gestionnaire ISR pour la minuterie de réception et les données statiques IRReceiver et irparams. 
// Economise 450 octets de mémoire de programme et 269 octets de RAM lorsque les fonctions de réception ne sont pas nécessaires.
#define DISABLE_CODE_FOR_RECEIVER 
#endif

/*
 * Cet include définit les numéros actuels des broches comme IR_RECEIVE_PIN, IR_SEND_PIN pour de nombreuses cartes et architectures différentes.
 */
#include "PinDefinitionsAndMore.h"
#include <IRremote.hpp> // Intégration de la bibliothèque

void setup() {
    pinMode(LED_BUILTIN, OUTPUT);

    Serial.begin(115200);
    while (!Serial)
        ; // Attendre que Serial soit disponible. En cours d'optimisation pour certains cœurs.

    // Juste pour savoir quel programme fonctionne sur mon Arduino
    Serial.println(F("KY-005 : Test d'émetteur infrarouge"));
    Serial.print(F("Envoyer des signaux IR à la broche "));
    Serial.println(IR_SEND_PIN);

    /*
     * La mise en place de la bibliothèque IR. C'est tout !
     */
    // Commencez par utiliser IR_SEND_PIN -défini dans PinDefinitionsAndMore.h- comme broche d'émission et activez la LED de retour sur la broche LED de retour standard.
    IrSender.begin();
    disableLEDFeedback(); // Désactiver la LED de rétroaction sur la broche standard de la LED de rétroaction
}

/*
 * Configuration des données à envoyer.
 * Dans la plupart des protocoles, les données sont envoyées avec une adresse constante de 8 (ou 16) octets.
 * et une commande variable de 8 bits.
 * Il y a des exceptions comme Sony et Denon qui ont une adresse de 5 bits.
 */
uint8_t sCommand = 0x34;
uint8_t sRepeats = 0;

void loop() {
    /*
     * Afficher les valeurs d'émission actuelles
     */
    Serial.println();
    Serial.print(F("Maintenant, l'envoi est en cours : Adresse=0x00, Commande=0x"));
    Serial.print(sCommand, HEX);
    Serial.print(F(", Répétitions="));
    Serial.print(sRepeats);
    Serial.println();

    Serial.println(F("Envoi de NEC standard avec adresse 8 bits"));
    Serial.flush();

    // La sortie du récepteur pour la première boucle doit être : Protocol=NEC Address=0x102 Commande=0x34 Raw- Dates=0xCB340102 (32 bits)
    IrSender.sendNEC(0x00, sCommand, sRepeats);

    /*
     * Incrémenter les valeurs d'émission
     */
    sCommand += 0x11;
    sRepeats++;
    // Le clip se répète à 4
    if (sRepeats > 4) {
        sRepeats = 4;
    }

    delay(1000);  // Le délai doit être supérieur à 5 ms (RECORD_GAP_MICROS), sinon le récepteur le voit comme un signal long
}