KY-005 Infrared transmitter

This module contains a light-emitting diode that emits infrared light. Infrared light is invisible to the human eye, but it is often used in many practical applications, such as remote controls or object recognition. The diode operates with a voltage of 1.1 V and a current of 20 mA. Depending on the input voltage, it is important to use series resistors to protect the LED and ensure smooth operation. These series resistors ensure that the correct amount of current flows through the diode, allowing it to be used effectively and safely. The module is ideal for projects that require infrared light and provides a reliable and simple solution for your infrared applications.

Series resistors:

Pin assignment

for more advanced users

On the PCB there is the possibility to directly solder the required resistor. The place for soldering the resistor is located directly above the connection pins on the PCB.

When soldering on the resistor, the pin assignment changes as follows:

for beginners

Code-Example

With the help of the two sensor modules KY-005 and KY-022 a system with infrared remote control and infrared receiver can be built. For this purpose, two Arduinos are required in addition to the two modules. These then act as transmitters and receivers of the signals.

To load the following code example onto your Arduino, we recommend using the Arduino IDE. In the IDE, you can select the appropriate port and the correct board for your device. For the following code example an additional library is needed:

IRremote by Ken Shirriff | published under the MIT license.

You can easily add these libraries via the library manager of the Arduino IDE.

In infrared transmitting systems there are different protocols in which the data can be sent. In the following example, the NEC protocol is used for sending. Documentation.Please note: For the execution of the code example an additional file is necessary. This opens automatically as soon as you open the sample code from the IRremote library. Therefore, first open the example code via the following path: File > Examples > IRremote > SimpleSender.

Now you can replace the example code with our modified example. To upload the code to the Arduino, simply click on the upload button.

/*
 * SimpleSender.cpp
 *
 * Demonstrates the sending of IR codes in standard format with address and command
 * An extended example for sending can be found as SendDemo.
 *
 *  Copyright (C) 2020-2022  Armin Joachimsmeyer
 *  armin.joachimsmeyer@gmail.com
 *
 * This file is part of Arduino-IRremote https://github.com/Arduino-IRremote/Arduino-IRremote.
 *
 *  MIT License
 */
#include <Arduino.h>

#if !defined(ARDUINO_ESP32C3_DEV) // This is due to an error in the RISC-V compiler, which requires unused function sections :-(.
// Deactivates static receiver code such as the ISR handler for the receive timer and static IR receiver and irparams data. 
// Saves 450 bytes of program memory and 269 bytes of RAM if the receive functions are not required.
#define DISABLE_CODE_FOR_RECEIVER 
#endif

/*
 * This include defines the current pin numbers for pins such as IR_RECEIVE_PIN, IR_SEND_PIN for many different boards and architectures
 */
#include "PinDefinitionsAndMore.h"
#include <IRremote.hpp> // Including the library

void setup() {
    pinMode(LED_BUILTIN, OUTPUT);

    Serial.begin(115200);
    while (!Serial)
        ; // Wait for Serial to become available. Will be optimized away for some cores.

    // Just to know which program is running on my Arduino
    Serial.println(F("KY-005: Infrared transmitter test"));
    Serial.print(F("Send IR signals to pin "));
    Serial.println(IR_SEND_PIN);

    /*
     * Setting up the IR library. That's it already!
     */
    // Start with IR_SEND_PIN - which is defined in PinDefinitionsAndMore.h - as the send pin and activate the feedback LED on the standard feedback LED pin
    IrSender.begin();
    disableLEDFeedback(); // Deactivate feedback LED on the standard feedback LED pin
}

/*
 * Set up the data to be sent.
 * With most protocols, the data is sent with a constant 8- (or 16-byte) address
 * and a variable 8-bit command.
 * There are exceptions, such as Sony and Denon, which have a 5-bit address.
 */
uint8_t sCommand = 0x34;
uint8_t sRepeats = 0;

void loop() {
    /*
     * Display current transmission values
     */
    Serial.println();
    Serial.print(F("Now being sent: address=0x00, command=0x"));
    Serial.print(sCommand, HEX);
    Serial.print(F(", repeats="));
    Serial.print(sRepeats);
    Serial.println();

    Serial.println(F("Sending standard NEC with 8-bit address"));
    Serial.flush();

    // The receiver output for the first loop must be: Protocol=NEC Address=0x102 Command=0x34 Raw-Data=0xCB340102 (32 bits)
    IrSender.sendNEC(0x00, sCommand, sRepeats);

    /*
     * Increment send values
     */
    sCommand += 0x11;
    sRepeats++;
    // Clip repeats at 4
    if (sRepeats > 4) {
        sRepeats = 4;
    }

    delay(1000);  // Delay must be greater than 5 ms (RECORD_GAP_MICROS), otherwise the receiver sees it as a long signal
}